home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Run Magazine ReRun 1985 Summer
/
rerun-1985-summer-side-b.d64
/
sound sampler
(
.txt
)
< prev
next >
Wrap
Commodore BASIC
|
2022-09-20
|
3KB
|
160 lines
5 print"[147]"
10 s=54272:forl=0to24:pokes+l,.:next
20 v=s+24:w=s+4:fu=s+1:fl=s:ad=s+5:sr=s+6:sl=s+14:su=s+15:pokev,15:pokead,15
25 print" [158]*** sound effects sampler[146] ***"
30 print" by bruce bartlett[154]"
31 print"a[146] echoing ufo takeoff"
32 print"b[146] pulsing ufo takeoff"
33 print"c[146] crystal goblet"
34 print"d[146] alien planet"
35 print"e[146] computer computing"
36 print"f[146] chipmunk fight"
37 print"g[146] beating rising buzzer"
38 print"h[146] seasick"
39 print"i[146] rubber band"
40 print"j[146] chime"
41 print"k[146] spinning falling wheel"
42 print"l[146] bwee"
43 print"m[146] cosmic rays"
44 print"n[146] pulse sweep"
45 print"o[146] ow"
46 print"p[146] warbling"
47 print"q[146] deedle deedle"
49 print"[159] type the letter of your choice[154]"
50 ifa>0anda<18thenprint"":forn=1toa+3:print:next:print"[154]"chr$(a+64)"[146]"
55 pokead,15:pokesr,0
60 geta$:ifa$=""then60
70 a=asc(a$)-64:ifa<1ora>17then60
72 print"":forn=1toa+3:print:next:print"[158]"chr$(a+64)"[146]"
75 ifa=16then1600
77 ifa=17then1700
80 onagoto100,200,300,400,500,600,700,800,900,1000,1100,1200,1300,1400,1500
100 rem ***echoing ufo takeoff***
110 pokesr,8
120 pokew,21
130 pokesl,67:pokesu,12
140 forf=0to255:pokefu,f:pokefl,f:next
150 pokew,20:fort=1to100:nextt
160 goto50
200 rem ***pulsing ufo takeoff***
210 forf=0to155:pokew,17:pokefu,f:fort=1to6:nextt
220 pokew,129:fort=1to50:nextt
230 nextf
240 pokew,128
250 goto50
300 rem crystal goblet
310 pokes+18,17:pokew,19
320 pokesu,64
330 forn=1to4
340 forf=1to255:pokefu,f:nextf
350 forf=255to1step-1:pokefu,f:nextf
360 nextn
370 pokew,18:goto50
400 rem ***alien planet***
410 pokesl,67:pokesu,12
420 pokew,21
430 forn=1to4
440 forf=0to255:pokefu,f:nextf
450 forf=255to0step-1:pokefu,f:nextf
460 nextn
470 pokew,20:goto50
500 rem ***computer computing***
510 pokesl,240:pokesu,12
520 pokew,19
530 forn=1to50:f=int(rnd(1)*255)+1:pokefu,f
540 fort=1to60:next
550 nextn
560 pokew,18:goto50
600 rem ***chipmunk fight***
610 pokew,21
620 forn=1to150:f=int(rnd(1)*255)+1
630 pokefu,f:pokesu,f
640 fort=1to12:nextt
650 nextn
660 pokew,20:goto50
700 rem ***beating rising buzzer***
710 pokead,9:pokesu,3
720 pokesr,64+12
730 pokefu,4:pokefl,10
740 pokew,21
750 forf=0to255step.3:pokesl,f:next
760 pokew,20:fort=1to1000:next:goto50
800 rem ***seasick***
810 pokead,63:pokefu,4:pokefl,10:pokesu,10
820 pokew,21
830 forn=1to4
840 forf=0to255:pokesl,f:nextf
850 forf=255to0step-1:pokesl,f:nextf
860 nextn
870 pokew,20:goto50
900 rem ***rubber band***
910 pokead,10:pokesr,64+9
920 pokefu,67:pokefl,12:pokesu,5
930 pokew,19
940 forf=0to255step1.3:pokesl,f:next
950 pokew,18:fort=1to500:next:goto50
1000 rem ***chime***
1010 pokead,10:pokesr,64+11
1020 pokesu,10:pokesl,10
1030 pokefu,4:pokew,21:fort=1to50:next
1040 pokew,20:fort=1to1800:next
1050 goto50
1100 rem ***spinning falling wheel***
1110 pokev,15+32:pokes+23,239
1120 pokew,33
1130 forsp=10to255
1140 forf=255to0step-sp:pokefu,f:pokes+22,f:next
1150 nextsp
1160 pokew,32:pokes+23,0:goto50
1200 rem ***bwee***
1210 pokead,119
1220 forn=1to30
1230 pokew,17
1240 forf=int(rnd(.)*50)+50toint(rnd(.)*150)+50step2:pokefu,f:next:pokew,16
1250 nextn
1260 goto50
1300 rem ***cosmic rays***
1310 pokead,119
1320 forn=1to15
1330 pokew,33
1340 forf=int(rnd(.)*150)+50toint(rnd(.)*50)step-1
1350 pokefu,f:nextf
1360 pokew,32
1370 nextn
1380 goto50
1400 rem ***pulse sweep***
1410 pokefu,2:pokefl,12:pokew,65:pl=54274:pu=54275
1420 forn=1to3
1430 forl=0to255step2:pokepl,l:pokepu,0:next
1440 forl=255to0step-2:pokepl,l:pokepu,0:next
1450 nextn
1460 pokew,64:goto50
1500 rem ***ow***
1510 pokead,47:pokes+23,239:pokev,15+32
1520 forn=1to10
1530 pokefu,int(rnd(.)*5)+2
1540 pokew,33
1550 forsw=100to0step-3
1560 pokes+22,sw:nextsw
1570 pokew,32:fort=1to100:next
1580 nextn
1590 pokes+23,0:pokev,15:goto50
1600 rem ***warbling***
1610 pokew,17:forn=1to30
1620 forf=50to200step20:pokefu,f:nextf
1630 nextn
1640 forn=1to20
1650 forf=50to200step10:pokefu,f:nextf
1660 nextn
1670 pokew,16:goto50
1700 rem ***deedle deedle***
1710 pokew,33:ford=100to0step-5
1720 pokefu,64:fort=1tod:next
1730 pokefu,54:fort=1tod:next
1740 nextd
1750 ford=0to100step5
1760 pokefu,64:fort=1tod:next
1770 pokefu,54:fort=1tod:next
1780 nextd
1790 pokew,32:goto50